camera {  //VideoCamera
  location  <          0,      -4.000,      15.000>
  sky       <    0.00000,     0.00000,     1.00000>
  up        <        0.0,         0.0,         1.0>
  right     <    1.35836,         0.0,         0.0>
  angle         40.00000
  look_at   <          0,       0.000,       0.000>
}

light_source {<0.0, 0.0, 0.0>
  color rgb <1.000, 1.000, 1.000>
  translate  <0.0, 7.0, 20.0>
}

//background { color <1.000,1.000,1.000> }

plane {
  z,0
  pigment {checker
          color rgb <1.0, 1.0, 1.0>
          color rgb <0.0, 0.0, 0.0>
          }
  finish {ambient 0.65}
  rotate -45.0*x
  translate  -4.0*z
}

#declare Soft_Silver = 
   material
   {   
      texture
      {      
         pigment
         {
            color rgb <0.94, 0.93, 0.83>
         }      
         finish
         {
            ambient 0.2
            diffuse 0.35
            brilliance 1.5
            specular 0.85
            roughness 0.01
            reflection 0.05
         }
      }
   }

//La molla
union
{
   #declare L    = 8;       //Lunghezza max
   #declare N    = 30;      //Numero di spire; per cambiare verso di rotazione delle spire
                            //basta cambiare il segno di N
   #declare R1   = 0.5;     //Raggio dell'avvolgimento
   #declare R2   = 0.04;    //Raggio del filo
   #declare D    = 2000;    //Livello di dettaglio
   
   #declare C    = 0;
   #declare W    = 2*pi*N/L; 
   #while (C<D)
      #declare Value1 = (  C  /D-0.5)*L;
      #declare Value2 = ((C+1)/D-0.5)*L;

      #declare Punto1y= -R1*cos(Value1*W);
      #declare Punto1z= R1*sin(Value1*W);

      #declare Punto2y= -R1*cos(Value2*W);
      #declare Punto2z= R1*sin(Value2*W);
      
      #declare Punto1x= -L/2+1.25*(Value1+0.4*L)*(1-exp(-exp(Value1+0.4*L)))-1.25*(Value1-0.4*L)*(1-exp(-exp(Value1-0.4*L)));
      #declare Punto2x= -L/2+1.25*(Value2+0.4*L)*(1-exp(-exp(Value2+0.4*L)))-1.25*(Value2-0.4*L)*(1-exp(-exp(Value2-0.4*L)));
      
      #declare Point1 = Punto1x*x+Punto1y*y+Punto1z*z;
      #declare Point2 = Punto2x*x+Punto2y*y+Punto2z*z;

      sphere {Point1, R2}
      cylinder {Point1, Point2, R2}       
      
      #declare C = C+1;
   #end
   material {Soft_Silver}
}